Artwork | Email

Pov-Ray source for Water Sphere

// Persistence of Vision Ray Tracer Scene Description File
// File: water_sphere.pov
// Vers: 3
// Desc: Glass sphere supported above some highly reflective water. Not a very
//       complex scene but very visually appealing. The reflections in this image
//       are very nice.
// Date: 07/31/2000
// Auth: Jim Lowell - jlowell@visi.com

#version 3

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

camera
{
  location  <0,  0, -40>
  look_at   <0, -5,  0>
}

light_source
{
  0*x
  color red 1.50  green 1.50 blue 1.50
  translate <10, 10, -30>
}

light_source
{
  0*x
  color red 0.50  green 0.50 blue 0.50
  translate <-10, -20, -30>
}

plane { y,-15
  pigment { SkyBlue }
  finish { 
    roughness 0.001
//    ambient 0
    diffuse 0.2
    reflection 0.9
    ior 1.5
  }
  normal { bumps 0.1 }
}

sphere { <0,0,0>,10
  texture { NBglass }
}

cylinder { <0,-100,0>,<0,-10.5,0>,5 texture { Brass_Metal }  }

#declare I = 0
#while (I < 23)
  torus{
    4.0,0.5
    texture { Brass_Metal }
    rotate < 0, 0, 45 >
    translate < 7.5, -7.5, 0 >
    rotate < 0, 15 * I, 0 >
  }
  #declare I = I + 1
#end

#declare I = 0
#while (I < 18)
  #declare J=0
    #while (J < 20)
      torus { 20, 4
        texture
        {
          pigment {checker color rgb 1 color rgb 0 scale 20 }
          finish {reflection 0.2}
        }
        translate < 200, (J * 20) - 100, 0>
        rotate <0,I * 20,0>
      }
      cylinder { <0,-400,0>,<0,400,0>,16
        texture { Polished_Chrome }
        translate < 200, (J * 20) - 100, 0>
        rotate <0,I * 20,0>
      }
      #declare J = J + 1
    #end
  #declare I = I + 1
#end