Artwork | Email

Pov-Ray source for Tile Tilt

// Persistence of Vision Ray Tracer Scene Description File
// File: tiletilt.pov
// Vers: 3
// Desc: Just a little goofing around one night
// Date: 08/15/2000
// Auth: Jim Lowell - jlowell@visi.com

#version 3

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

camera
{
  location  <-2, 25, -15>
  look_at   <0,  0,  0>
}

plane { y,50 pigment { SteelBlue } finish { Dull ambient 0.5 } normal { bumps 0.1 } }

light_source
{
  0*x
  color White * 2
  translate <-20, 40, -20>
}

#declare mirror=union
{
  box { <-2,0,-2>,<2,0.1,2> texture { Polished_Chrome } }
  cylinder { <-2,1,0>,<2,1,0>,0.2 texture { Polished_Brass } }
  cylinder { < 1,0, 1>,<2,1,0>,0.05 texture { Polished_Brass } }
  cylinder { < 1,0,-1>,<2,1,0>,0.05 texture { Polished_Brass } }
  cylinder { <-1,0, 1>,<-2,1,0>,0.05 texture { Polished_Brass } }
  cylinder { <-1,0,-1>,<-2,1,0>,0.05 texture { Polished_Brass } }
}

#declare J=0
#while (J < 36)
  #declare I=0
  #while (I < 18)
    object { mirror rotate < 0,0,I * 5 > translate < I * 2,0,0> rotate<0,J*10,0> }
    #declare I=I+1
  #end
  #declare J=J+1
#end