Artwork | Email

Pov-Ray source for tilefloor_peoplenet

// Persistence of Vision Ray Tracer Scene Description File
// File: tilefloor_peoplenet.pov
// Vers: 3.5
// Desc: Playing around with transparent tiles & stuff
// Date: 7/27/2008
// Auth: Jim Lowell - jlowell@visi.com

#version 3.6

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

camera
{
  location  <-2,5,-2.5>
  look_at   <0,0.5,0>
}

// Sky sphere
sky_sphere { pigment { Bright_Blue_Sky scale 0.5 } }

// Floor
plane { y,0 pigment { White } finish { Dull } }

// Declare a tile
declare atile=difference {
  superellipsoid { <0.2, 0.2> scale <0.5,0.125,0.5> }
  box { <-10,-10,-10>,<10,0,10> }
}

// Draw the floor
#declare I=0;
#while (I<40)
  #declare J=0;
  #while (J < 40)
    object { atile translate <I-20,0,J-20> texture { NBglass } finish { reflection 0.35 }  }
    #declare J=J+1;
  #end
  #declare I=I+1;
#end

/* BEGIN DECLARATION OF PEOPLENET LOGO OBJECT */
#declare peoplenet_logo=union {

  /* Black swoopey thing */
  prism {
     bezier_spline
     0, 1, 48,
     <0,0>, <1,5.6>, <12,8.2>, <22.4,8>,
     <22.4,8>, <32.4,7.8>, <42,4.7>, <42,0.7>,
     <42,0.7>, <42.1,-4>, <32,-6.8>, <22.1,-6.5>,
     <22.1,-6.5>, <9.2,-6>, <5.8,-2.2>, <5.4,-1.8>,
     <5.4,-1.8>, <5.2,-1.6>, <5.4,-1.5>, <5.7,-1.7>,
     <5.7,-1.7>, <6.1,-1.95>, <9.2,-4.1>, <16.2,-4.6>,
     <16.2,-4.6>, <28.3,-5.2>, <38.2,-3>, <38,0>,
     <38,0>, <37.1,5.5>, <5.95,6.95>, <2.6,-1.4>,
     <2.6,-1.4>, <1.8,-3.5>, <5.8,-5.4>, <7.9,-6.35>,
     <7.9,-6.35>, <10.25,-7.2>, <14.15,-7.85>, <16.7,-8.1>,
     <16.7,-8.1>, <17.15,-8.2>, <17.1,-8.6>, <16.6,-8.52>,
     <16.6,-8.52>, <2.2,-7.2>, <-0.45,-2.1>, <0,0>

    translate <-19,0,0>
    pigment { Black }
    finish { Dull ambient 1.0 }
  }
  
  /* Blue dot in the middle */
  cylinder {
    <-2,0,0>,<-2,1,0>,2.5
    pigment { Blue }
    finish { Dull ambient 1.0 }
  }

  /* Blue arch to the left of the blue dot */
  difference {
    cylinder { <0,0,0>,<0,0.9,0>,1 }
    cylinder { <0.6,-1,0>,<0.6,2,0>,1.5 }
    translate <0.7,0,0>
    scale <34,1,34>
    translate <0,0,-6>
    pigment { Blue }
    finish { Dull ambient 1.0 }
  }
}
/* END DECLARATION OF PEOPLENET LOGO OBJECT */

object { peoplenet_logo scale 0.9 rotate <0,20,0> translate <15,30,30> }

light_source {
  0*x                  // light's position (translated below)
  color White * 1    // light's color
  translate <0,10000,0>
}