Artwork | Email

Pov-Ray source for PeopleNet Sphere 2

Note: If you wish to render this image as I have presented it, you will need this sgrid.gif image referenced in the source.

// Persistence of Vision Ray Tracer Scene Description File
// File: pnet_sphere2.pov
// Vers: 3.1
// Desc: PeopleNet logo with light streaming out of it
// Date: 3/14/2003
// Auth: Jim Lowell - jlowell@visi.com

#version 3.1

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

camera
{
  location  <0, -40, -60>
  look_at   <0, 3, 0>
}

/* BEGIN DECLARATION OF PEOPLENET LOGO OBJECT */
#declare peoplenet_logo=union {

  /* Black swoopey thing */
  prism {
     bezier_spline
     0, 1, 48,
     <0,0>, <1,5.6>, <12,8.2>, <22.4,8>,
     <22.4,8>, <32.4,7.8>, <42,4.7>, <42,0.7>,
     <42,0.7>, <42.1,-4>, <32,-6.8>, <22.1,-6.5>,
     <22.1,-6.5>, <9.2,-6>, <5.8,-2.2>, <5.4,-1.8>,
     <5.4,-1.8>, <5.2,-1.6>, <5.4,-1.5>, <5.7,-1.7>,
     <5.7,-1.7>, <6.1,-1.95>, <9.2,-4.1>, <16.2,-4.6>,
     <16.2,-4.6>, <28.3,-5.2>, <38.2,-3>, <38,0>,
     <38,0>, <37.1,5.5>, <5.95,6.95>, <2.6,-1.4>,
     <2.6,-1.4>, <1.8,-3.5>, <5.8,-5.4>, <7.9,-6.35>,
     <7.9,-6.35>, <10.25,-7.2>, <14.15,-7.85>, <16.7,-8.1>,
     <16.7,-8.1>, <17.15,-8.2>, <17.1,-8.6>, <16.6,-8.52>,
     <16.6,-8.52>, <2.2,-7.2>, <-0.45,-2.1>, <0,0>

    translate <-19,0,0>
  }
  
  /* Blue dot in the middle */
  cylinder {
    <-2,0,0>,<-2,1,0>,2.5
  }

  /* Blue arch to the left of the blue dot */
  difference {
    cylinder { <0,0,0>,<0,0.9,0>,1 }
    cylinder { <0.6,-1,0>,<0.6,2,0>,1.5 }
    translate <0.7,0,0>
    scale <34,1,34>
    translate <0,0,-6>
  }
}
/* END DECLARATION OF PEOPLENET LOGO OBJECT */

#declare Blue_Glass =
texture { 
    NBglass
    pigment { rgbf <0.7, 0.8, 0.9, 0.8> }
}

#declare pnetsphere=
union {
  difference {
    sphere { <0,0,0>,1000 translate <0,0,990> pigment { image_map { gif "sgrid.gif" } scale 50 rotate 30 } finish { Dull ambient 1.0 } }
    sphere { <0,0,0>,998 translate <0,0,990> pigment { White } finish { Dull ambient 0.1 } }
    object { peoplenet_logo rotate <-90,0,0> scale <1,1,30> pigment { White } finish { Dull ambient 0.1 } }
  }
  sphere { <0,0,0>,999 translate <0,0,990> texture { Blue_Glass } }
}

media {
  scattering { 1, rgb 0.02}
  intervals 120
  samples 1, 10         
  confidence 0.9999
  variance 1/1000
  ratio 0.9
}

object { pnetsphere }

// Enclosing box that provides the background color
difference {
  box { <-10001,-10001,-10001>,<10001,10001,10001> }
  box { <-10000,-10000,-10000>,<10000,10000,10000> }
  pigment { Blue } finish { Dull }
}  

// Light above the sphere
light_source {
  0*x
  color White * 0.5
  translate <0,40,-300>
}

// Light inside (this is the light that streams out)
light_source {
  0*x
  color White * 5
  translate <0,0,290>
}